Project:SPARQL/examples

Vzorové dotazy

Všechny pojmy s výkladem

PREFIX zwb: <https://tdkiv.wikibase.cloud/entity/>
PREFIX zdp: <https://tdkiv.wikibase.cloud/prop/direct/>
PREFIX zp: <https://tdkiv.wikibase.cloud/prop/>
PREFIX zps: <https://tdkiv.wikibase.cloud/prop/statement/>
PREFIX zpq: <https://tdkiv.wikibase.cloud/prop/qualifier/>
PREFIX zpr: <https://tdkiv.wikibase.cloud/prop/reference/>
PREFIX zno: <https://tdkiv.wikibase.cloud/prop/novalue/>

select ?item ?itemLabel ?vyklad where {
  
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs,en". }
  

  ?item zdp:P16 zwb:Q4397 .
  ?item zdp:P1 ?vyklad .
 
  }

ORDER BY ASC(?itemLabel)

Try it!

Počty citací zdrojů použitých při vytváření terminologické databáze

#defaultView:BubbleChart
PREFIX zp: <https://tdkiv.wikibase.cloud/prop/>
PREFIX zps: <https://tdkiv.wikibase.cloud/prop/statement/>
PREFIX zpr: <https://tdkiv.wikibase.cloud/prop/reference/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX prov: <http://www.w3.org/ns/prov#>
SELECT ?zdroj ?stitek (COUNT(?zdroj) AS ?pocet_citaci) WHERE {
  ?item zp:P1 ?vykladstatement.
  ?vykladstatement zps:P1 ?vyklad;
    prov:wasDerivedFrom ?ref.
  ?ref zpr:P22 ?zdroj.
  OPTIONAL {
    ?zdroj rdfs:label ?zdrojLabel.
    FILTER((LANG(?zdrojLabel)) = "cs")
  }
  OPTIONAL {
    ?zdroj owl:sameAs ?presmerovany_zdroj.
    ?presmerovany_zdroj rdfs:label ?presmerovany_label.
  }
  BIND(IF(BOUND(?presmerovany_label), ?presmerovany_label, ?zdrojLabel) AS ?stitek)
}
GROUP BY ?zdroj ?zdrojLabel ?presmerovany_zdroj ?presmerovany_label ?stitek
ORDER BY DESC (?pocet_citaci)

Try it!